92 lines
2.9 KiB
Groovy
92 lines
2.9 KiB
Groovy
apply plugin: 'com.android.application'
|
|
|
|
repositories {
|
|
//noinspection JcenterRepositoryObsolete
|
|
jcenter {
|
|
content {
|
|
includeVersion "mobi.upod", "time-duration-picker", "1.1.3"
|
|
}
|
|
}
|
|
}
|
|
|
|
def getVersionCode = { ->
|
|
try {
|
|
def stdout = new ByteArrayOutputStream()
|
|
exec {
|
|
commandLine 'git', 'rev-list', '--first-parent', '--count', 'master'
|
|
standardOutput = stdout
|
|
}
|
|
return Integer.parseInt(stdout.toString().trim())
|
|
}
|
|
catch (ignored) {
|
|
return -1;
|
|
}
|
|
}
|
|
|
|
def getVersionName = { ->
|
|
try {
|
|
def stdout = new ByteArrayOutputStream()
|
|
exec {
|
|
commandLine 'git', 'describe', '--tags', '--dirty'
|
|
standardOutput = stdout
|
|
}
|
|
return stdout.toString().trim()
|
|
}
|
|
catch (ignored) {
|
|
return null;
|
|
}
|
|
}
|
|
|
|
android {
|
|
compileSdk 34
|
|
buildToolsVersion = '34.0.0'
|
|
defaultConfig {
|
|
applicationId "net.typeblog.shelter"
|
|
minSdkVersion 24
|
|
targetSdkVersion 34
|
|
versionCode getVersionCode()
|
|
versionName getVersionName()
|
|
testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
|
|
}
|
|
buildTypes {
|
|
release {
|
|
minifyEnabled true
|
|
shrinkResources true
|
|
proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
|
|
}
|
|
}
|
|
applicationVariants.all { variant ->
|
|
if (variant.name == "debug") {
|
|
variant.outputs.each { o -> o.versionCodeOverride = System.currentTimeSeconds() }
|
|
}
|
|
}
|
|
compileOptions {
|
|
sourceCompatibility JavaVersion.VERSION_1_8
|
|
targetCompatibility JavaVersion.VERSION_1_8
|
|
}
|
|
lint {
|
|
disable 'MissingTranslation', 'ExtraTranslation', 'GoogleAppIndexingWarning', 'InvalidFragmentVersionForActivityResult'
|
|
}
|
|
buildFeatures {
|
|
aidl true
|
|
}
|
|
namespace 'net.typeblog.shelter'
|
|
}
|
|
|
|
dependencies {
|
|
implementation fileTree(include: ['*.jar'], dir: 'libs')
|
|
implementation 'androidx.legacy:legacy-support-core-ui:1.0.0'
|
|
implementation 'androidx.fragment:fragment:1.6.1'
|
|
implementation 'androidx.appcompat:appcompat:1.7.0-alpha03'
|
|
implementation 'androidx.preference:preference:1.2.1'
|
|
implementation 'androidx.constraintlayout:constraintlayout:2.1.4'
|
|
implementation 'com.google.android.material:material:1.10.0'
|
|
implementation 'androidx.localbroadcastmanager:localbroadcastmanager:1.1.0'
|
|
implementation 'mobi.upod:time-duration-picker:1.1.3'
|
|
debugImplementation project(path: ':setup-wizard-lib', configuration: 'gingerbreadCompatDebugRuntimeElements')
|
|
releaseImplementation project(path: ':setup-wizard-lib', configuration: 'gingerbreadCompatReleaseRuntimeElements')
|
|
testImplementation 'junit:junit:4.13.2'
|
|
androidTestImplementation 'androidx.test:runner:1.6.0-alpha04'
|
|
androidTestImplementation 'androidx.test.espresso:espresso-core:3.6.0-alpha01'
|
|
}
|