70 lines
2 KiB
Bash
70 lines
2 KiB
Bash
# Maintainer: Peter Cai <peter AT typeblog DOT net>
|
|
# Contributor: Chocobo1 <chocobo1 AT archlinux DOT net>
|
|
|
|
pkgname=wpa_supplicant-raspberrypi-git
|
|
pkgver=2.11.r798.gce80c6464
|
|
pkgrel=1
|
|
pkgdesc="A daemon program controlling the wireless connection, patched for Raspberry Pi"
|
|
arch=('aarch64')
|
|
url="https://w1.fi/wpa_supplicant/"
|
|
license=('BSD')
|
|
depends=('glibc' 'openssl' 'libdbus' 'libnl' 'readline' 'pcsclite')
|
|
optdepends=('wpa_supplicant_gui: GUI frontend')
|
|
makedepends=('git')
|
|
provides=("wpa_supplicant=$pkgver")
|
|
conflicts=('wpa_supplicant')
|
|
source=("git+https://w1.fi/hostap.git"
|
|
"config"
|
|
"0001-Revert-Mark-authorization-completed-on-driver-indica.patch")
|
|
sha256sums=('SKIP'
|
|
'1e32af4a1a147ee75358fd0b5636fb41332a7b91ec7a904292178256f735e9d2'
|
|
'bc21fa6bbbdf6f206a7cfea3d17ca6e6f9bf0b7933ec18376dae626e80787e5d')
|
|
|
|
|
|
prepare() {
|
|
cd "$srcdir"
|
|
|
|
cp "config" "hostap/wpa_supplicant/.config"
|
|
|
|
cd "hostap"
|
|
|
|
git apply ../0001-Revert-Mark-authorization-completed-on-driver-indica.patch
|
|
}
|
|
|
|
pkgver() {
|
|
cd "hostap/wpa_supplicant"
|
|
|
|
git describe --long --tags | sed 's/^hostap_//;s/\([^-]*-g\)/r\1/;s/[_-]/./g'
|
|
}
|
|
|
|
build() {
|
|
cd "hostap/wpa_supplicant"
|
|
|
|
export CFLAGS="$CPPFLAGS $CFLAGS"
|
|
make \
|
|
LIBDIR="/usr/lib" \
|
|
BINDIR="/usr/bin"
|
|
make \
|
|
LIBDIR="/usr/lib" \
|
|
BINDIR="/usr/bin" \
|
|
eapol_test
|
|
}
|
|
|
|
package() {
|
|
cd "hostap/wpa_supplicant"
|
|
|
|
make \
|
|
LIBDIR="/usr/lib" \
|
|
BINDIR="/usr/bin" \
|
|
DESTDIR="$pkgdir" \
|
|
install
|
|
|
|
install -Dm755 "eapol_test" -t "$pkgdir/usr/bin"
|
|
install -Dm644 "wpa_supplicant.conf" -t "$pkgdir/usr/share/doc/wpa_supplicant"
|
|
install -Dm644 "dbus/fi.w1.wpa_supplicant1.service" -t "$pkgdir/usr/share/dbus-1/system-services"
|
|
install -Dm644 "dbus/dbus-wpa_supplicant.conf" "$pkgdir/etc/dbus-1/system.d/wpa_supplicant.conf"
|
|
install -Dm644 "systemd"/*.service -t "$pkgdir/usr/lib/systemd/system"
|
|
|
|
sed -n '/This software may/,/OF SUCH DAMAGE./p' "README" > "COPYING"
|
|
install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/wpa_supplicant"
|
|
}
|